FunctX XQuery Function Library > XML Elements and Attributes > Modifying XML Attributes >

functx:add-attributes

Adds attributes to XML elements

Description

The functx:add-attributes function takes one or more XML element nodes, along with a sequence of attribute names and a sequence of attribute values, and returns a newly constructed element with those attributes added. The attribute names and values are positionally related, i.e. the first attribute name corresponds to the first attribute value, the second name to the second value, etc. It leaves all the original attributes and content of the element. Unlike the functx:add-or-update-attributes function, if it already has an attribute with the same name of one of $attrNames, its original value is retained and the value in $attrValues is ignored.

Each name must be specified as an xs:QName value. QNames can be constructed with calls to the xs:QName type constructor or the fn:QName function, as shown in the examples.

Note: this function is intended to change the way elements and attributes appear in the results of a query, not to update them in an XML database. To update your XML database, you should use the implementation-specific update functions of your processor.

Arguments and Return Type

XQuery Function Declaration

declare namespace functx = "http://www.functx.com";
declare function functx:add-attributes
  ( $elements as element()* ,
    $attrNames as xs:QName* ,
    $attrValues as xs:anyAtomicType* )  as element()? {

   for $element in $elements
   return element { node-name($element)}
                  { for $attrName at $seq in $attrNames
                    return if ($element/@*[node-name(.) = $attrName])
                           then ()
                           else attribute {$attrName}
                                          {$attrValues[$seq]},
                    $element/@*,
                    $element/node() }
 } ;

Examples

declare namespace new = "http://new";

<in-xml>
   <a>x</a>
   <b att1="x">x</b>
</in-xml>

functx:add-attributes(
   $in-xml/a, xs:QName('att1'), 1)

<a att1="1">x</a>

functx:add-attributes(
   $in-xml/a,
   (xs:QName('att1'),xs:QName('att2')),
   (1,2))

<a att1="1" att2="2">x</a>

functx:add-attributes(
   $in-xml/b,
   (xs:QName('att1'),xs:QName('att2')),
   (1,2))

<b att1="x" att2="2">x</b>

functx:add-attributes(
   $in-xml/a,
   xs:QName('new:att1'),
   1)

<a xmlns:new="http://new" new:att1="1">x</a>

functx:add-attributes(
   $in-xml/a,
   QName('http://new','new:att1'),
   1)

<a xmlns:new="http://new" new:att1="1">x</a>

See Also

History