FunctX XQuery Function Library > XML Elements and Attributes > Modifying XML Attributes >

functx:remove-attributes

Removes attributes from an XML element, based on name

Description

The functx:remove-attributes function removes attributes from a sequence of one or more elements. The $names argument is a sequence of strings that represent attribute names to remove. Prefixes can (and must) be used in the $names values for attributes that are prefixed in the input documents (using the same prefix). You can also specify wildcard values "*", "*:" and ":*" as the second argument. See the description for functx:name-test for details.

The function does not remove attributes from the descendants of the elements, just the elements themselves; see functx:remove-attributes-deep for this purpose.

Note: this function is intended to change the way elements and attributes appear in the results of a query, not to update them in an XML database. To update your XML database, you should use the implementation-specific update functions of your processor.

Arguments and Return Type

XQuery Function Declaration

declare namespace functx = "http://www.functx.com";
declare function functx:remove-attributes
  ( $elements as element()* ,
    $names as xs:string* )  as element() {

   for $element in $elements
   return element
     {node-name($element)}
     {$element/@*[not(functx:name-test(name(),$names))],
      $element/node() }
 } ;

Examples

<a attr1="123" attr2="456">abc</a>

<a xmlns:a="http://a"
    a:attr1="123" attr1="456">abc</a>

functx:remove-attributes(
     $in-xml-1, ('attr1','attr2'))

<a>abc</a>

functx:remove-attributes(
     $in-xml-1, ('attr1','attr3'))

<a attr2="456">abc</a>

functx:remove-attributes($in-xml-1, '*')

<a>abc</a>

functx:remove-attributes(
     $in-xml-2, ('a:attr1'))

<a attr1="456">abc</a>

Depends On

See Also

History