FunctX XQuery Function Library > Strings > Contains >

functx:contains-word

Whether one string contains another, as a separate word

Description

The functx:contains-word function returns true if $word is contained in $arg as a separate word. It must be delimited by non-word characters or the beginning or end of $arg. It is case insensitive; it matches a word even if the case is different.

A "non-word character" is one that in Unicode belongs in either the Punctuation, Separators or Other category. Generally, most punctuation and white space are considered non-word characters, while letters and digits are word characters.

Arguments and Return Type

XQuery Function Declaration

declare namespace functx = "http://www.functx.com";
declare function functx:contains-word
  ( $arg as xs:string? ,
    $word as xs:string )  as xs:boolean {

   matches(upper-case($arg),
           concat('^(.*\W)?',
                     upper-case(functx:escape-for-regex($word)),
                     '(\W.*)?$'))
 } ;

Examples

functx:contains-word('abc def ghi', 'def')

true

functx:contains-word('abc.def\ghi', 'def')

true

functx:contains-word('abc def ghi', 'abc')

true

functx:contains-word('abc', 'abc')

true

functx:contains-word('abcdef', 'abc')

false

Depends On

See Also

History